'=======================================================================================
'
' AUTHOR: 	Anthony Drewery
'
' DATE: 	23rd October 2006
'
' COMMENT: 	Exports a list login scripts for all users
'=======================================================================================

Const ForWriting = 2

'Path for the output file
filePath = "C:\WhichLoginScript.txt"

'Setup output file
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(filepath, ForWriting, True)

'Write Header row
objTextFile.writeLine("Display Name" & vbTab & "Logon Script" & vbTab & "DN")

'Create Objects for LDAP Queries
Set rootDSE = GetObject("LDAP://RootDSE")
DomainContainer = rootDSE.Get("defaultNamingContext")

Set conn = CreateObject("ADODB.Connection")
conn.Provider = "ADSDSOObject"
conn.Open "ADs Provider"

'LDAP query for all users
strLDAP = "<LDAP://" & DomainContainer & ">;(&(objectCategory=person)(objectClass=user));adspath;subtree"

'Get query results and output to file
Set oComm = CreateObject("ADODB.Command")
oComm.ActiveConnection = conn
oComm.CommandText = strLDAP
oComm.Properties("Sort on") = "DisplayName"
oComm.Properties("Page size") = 1500

Set rs = oComm.Execute

While Not rs.EOF
	
	Set FoundObject = GetObject (rs.Fields(0).Value)
			strRow = FoundObject.DisplayName & vbTab & FoundObject.scriptPath & vbTab & FoundObject.distinguishedName		
			objTextFile.writeLine(strRow)
	rs.MoveNext

Wend

MsgBox "Processing complete!"